摘 要VB 5.0/6.0的MSComm通信控件提供了一系列标准通信命令的接口，它允许建立串口连接，但在实际通信软件设计过程中，MSComm控件并非像想像中那样完美和容易控制，特别是在中文Windows下通信时更会出现问题。本文就MSComm控件在实际应用中可能出现的问题以及编程技巧进行探讨。
关键词 MsComm控件 串口通信 处理
1.MSComm控件的基础理论
一般说来，计算机都有一个或多个串行端口，它们依次为Com1、Com2、...。这些串口还提供了外部设备与PC进行数据传输和通信的通道，这些串口在CPU和外设之间充当解释器的角色。当字符数据从CPU发送给外设时，这些字符数据将被转换成串行比特流数据；当接收数据时，比特流数据被转换为字符数据传递给CPU。再进一步说，在操作系统方面，Windows用通信驱动程序(COMM.DRV)调用API函数发送和接收数据。当用通信控件或声明调用API函数时，它们由COMM.DRV解释并传递给设备驱动程序。作为一个VB程序员，要编写通信程序，只需知道通信控件提供给Windows通信API函数的接口即可，换句话说，只需设定和监视通信控件的属性和事件即可。
2.利用MSComm控件进行数据的接收和发送
搞清楚以上基本属性和事件后就可以开始编写通信程序了：在VB 5.0/6.0中新建一个工程文件，添加Microsoft Comm control 5.0组件，在窗体Form1中加入Command命令按钮并取名为cmdTest，MSComm控件取名为MSComm1，写入以下代码：
Private Sub cmdTest_Click()
MSComm1.CommPort = 1 '设定Com1口
If MSComm1.PortOpen = False Then
MSComm1.Settings = "9600,N,8,1" '9600波特率，无校验，8位数据位，1位停止位
MSComm1.PortOpen = True '打开串口
End If
MSComm1.OutBufferCount = 0 '清空发送缓冲区
MSComm1.InBufferCount = 0 '清空接收缓冲区
'发送字符数据,注意必须用回车符(vbCr)结束
MSComm1.Output="This is a good book!" & vbCr
'拨打电话号码或发送AT命令
MSComm1.Output="ATDT 0294563622" & vbCr
'发送字符数组数据，注意ByteArray必须事先定义赋值
Dim ByteArray as byte() '定义动态数组
ReDim ByteArray(1) '重定义数组大小
ByteArray(0)=0
ByteArray(1)=1
MSComm1.Output = ByteArray '发送字符数组数据
End Sub
Private Sub MSComm1_OnComm()
Select Case MSComm1.CommEvent
Case comEvReceive '接收字符数据
Dim Buffer As Variant
MSComm1.InputLen = 0
'当InputMode 属性值为0（文本模式）时,变量中含String型数据。
'当InputMode属性值为1（二进制模式）时,变量中含Byte型数组数据。
MSComm1.InputMode=comInputModeBinary
Buffer=MSComm1.Input '接收二进制数据
MSComm1.InputMode=comInputModeText
Buffer = MSComm1.Input
Case else
End Select
End Sub
3.中文Windows下的通信问题与解决方法
3.1 接收的数据少于发送的数据
如果通过MSComm控件一次性传送较多的二进制数据，那么，很可能收到的数据不足。例如在设置为2400bps传输率的情况下，一次性可以传输2048个字符数据，那么在大多数情况下一次只能收到1200个字符左右，这是因为新版的MSComm32.OCX中存在一个影响传输二进制数据的Bug。
32位Windows API函数使用了几个用COMMTIMEOUTS结构表示的限时变量，WriteTotalTimeOutConstant即是其中的一个，它被Windows内部设定为5000（即5秒），这个常量决定了在通信驱动程序停止传输之前花费在发送缓冲区中数据的时间的长短。5秒钟意味着通信速度为1200bps情况下仅能发送600个字符，2400bps情况下仅能发送1200个左右的字符。事实上，在一个缓冲区内一次性发送更多的数据是非常可能的。VB 5.0/6.0版本的MSComm控件有一个新增的重要的属性称为CommID，CommID指的是当串口被打开时，被API所调用的串口句柄（或标志），这也意味着能利用API接口函数去修改这个常量。每次串口关闭后，Windows会自动将之恢复为5000，所以，每次打开串口后需要重新设定。以下是API声明代码：
Type COMMTIMEOUTS
ReadIntervalTimeout As Long
ReadTotalTimeoutMultiplier As Long
ReadTotalTimeoutConstant As Long
WriteTotalTimeoutMultiplier As Long
WriteTotalTimeoutConstant As Long
End Type
Declare Function SetCommTimeouts Lib "Kernel32" (ByVal hFile As Long , _
lpCommTimeouts As COMMTIMEOUTS) As Long
Declare Function GetCommTimeouts Lib "Kernel32" (ByVal hFile As Long , _
lpCommTimeouts As COMMTIMEOUTS) As Long
Dim timeouts As COMMTIMEOUTS
Dim Ret As Long
If Comm1.PortOpen = False Then
Comm1.PortOpen = True
End If
'打开串口后重新设定串口句柄
Ret=GetCommTimeouts(Comm1.CommID,timeouts)
'Set some default timeouts
timeouts.ReadIntervalTimeout = 1
timeouts.ReadTotalTimeoutMultiplier = 1
timeouts.ReadTotalTimeoutConstant = 1
timeouts.WriteTotalTimeoutMultiplier = 1
timeouts.WriteTotalTimeoutConstant=(Comm1.OutBufferSize \ Val(Comm1.Settings))*10000+1000
Ret=SetCommTimeouts(Comm1.CommID,timeouts)
3.2 如何发送大于128的字符数据
在通信程序中，以单字符方式逐个发送数据时，每一个数据范围为0-255（即十六进制的00-FF）。在单字符版本的英文Windows或DOS版的BASIC程序中，只需要将相应的数据转换成相应的字符发送到通信端口即可。但在中文Windows下却行不通，假设在中文Windows下运行以下程序：
Dim i as Integer
For i = 0 To 255
MSComm1.Output = chr(i)
Next i
希望在接收端得到预期的0-255之间的数据，结果却是：前129个数据接收正确，为0-128，后面127个数据为126个0和一个255。造成这种结果的原因在于中文Windows使用的是双字节字符集(DBCS)系统。DBCS系统使用0-128之间的数字表示ASCII字符，大于128的数字仅作为前导字符，它只是显示是一个非拉丁语系的字符，而并不代表实际意义。上述程序在调用CHR()函数时用到了DBCS字符集，因此产生了此类错误。那么，如何发送大于128的数据呢？答案是使用字节数组，将以上程序改为：
Dim MyData(255) As Byte
For i = 0 To 255
MyData(i) = i
Next i
MSComm1.Output = MyData
Do
DoEvents
Loop Until MSComm1.OutBufferCount = 0
'接收过程
Private Sub MSComm1_OnComm()
Select Case MSComm1.CommEvent
Case comEvReceive
Dim Buffer As Variant
MSComm1.InputMode = comInputModeBinary
MSComm1.InputLen = 0
Buffer = MSComm1.Input
For i=LBound(Buffer) To UBound(Buffer)
Text1.Text= Buffer(i);
Next i
Case Else
End Select
End Sub
3.3 如何发送中文字符串
VB 5.0/6.0中可以直接把中文字符等同于英文字符发送，如：MSComm1.output="现在发送中文数据！"，但这种方法发送的中文数据不能太长，发送缓冲区和接收缓冲区的大小需设定为中文字符的两倍以上，而且发送与接收系统所处的操作系统版本最好要一致，否则会出现接收或发送缓冲区溢出之类的错误。这种方法可用于一般要求不太高的场合。除了上述方法外，还可以采用间接方式发送中文字符串。
在发送端将汉字或字符转换为机器内码或区位码数据数组，然后将转换后的数据发送到串口，在接收端接收到数据后，按照相反的顺序将得到的数据转换为相应的汉字或字符。在转换过程中，要用到位运算，如取得汉字的内码后需要将高字节和低字节分开，而VB 5.0/6.0中并没有提供此类函数，以下是求整数高、低字节的函数。
Public Function HiByte(a As Integer)
Dim b As Integer
b = a And &HFF00
b = b / 256
If b < 0 Then b = b + 256
HiByte = b
End Function
Public Function LowByte(a As Integer)
Dim b As Integer
b = a And &HFF
LowByte = b
End Function
3.4如何在通信过程中进行延时
在某些通信过程中，常常需要在发送完一组数据后进行一段延时，以等待对方处理上组数据，以下是延时函数代码。
Public Sub Delay(PauseTime As Single)
Dim Start
Start = Timer
'设定开始时间
Do While Timer < Start + PauseTime
DoEvents
Loop
End Sub
4.结束语
随着计算机应用领域的不断扩展，计算机之间的远程通信用得也越来越广泛。作为RAD开发工具代表的Visual Basic同样提供了一系列标准通信命令的接口，它允许建立串口连接，可以连接到其他通信设备（如Modem）、还可以发送命令、进行数据交换以及监视和响应在通信过程中可能发生的各种错误和事件等，可以满足通常情况下的串口通信需求。如果在实际应用过程中，能够很好的掌握MSComm控件的特性，灵活变通，就可以达到安全、稳定、高效通信的目的。
【参考文献】
1、周轶峰，杨建新，《Visual Basic 6.0 实用编程技术》，
中国水利水电出版社，1999
2、王建新，陈一飞等译，《Visual Basic 6.0 开发人员指南》，机械工业出版社，1999
需要完整，原创，优秀的毕业论文或职称论文请联系 ，可以帮到你！
|
